Bifurcation tBifurcation;
Slider tSlider;
Verhulst tVerhulst;
boolean drawn = false;

PFont font;
void setup() 
{ 
 // int h = screen.height;
 // h = (h - 50 - 30 ) /2;
  //h = 250;
  //println(h);
  //  size(h, (h * 2)+30);
  size(600,330);
  int h = 300;
  background(240); 
  font = loadFont("LucidaSansUnicode-9.vlw"); 
  textFont(font); 
  tBifurcation = new Bifurcation(h,30,h,h, 2.75, 4.0);
  tVerhulst = new Verhulst(0,30,h,h);
  tSlider = new Slider(h,0,h,30,10,0.5, 2.75, 4.0,h);

}
void draw(){ 
  if(!drawn){
    tBifurcation.display();
    loadPixels();
    drawn = true;
  }
  else{
    updatePixels();
  }
  tVerhulst.u = tSlider.value();
  tVerhulst.display();
  tSlider.display();

} 

class Verhulst{

  float w; // single bar width 
  float xpos; // rect xposition 
  float h; // rect height 
  float ypos ; // rect yposition 

  float x = 0.1;
  float u = 3.5;
  int n = 0;
  float x0 = x; 
  float x1 = 0; 

  Verhulst(float x, float y, float ww, float hh) { 
    w = ww;
    h= hh;
    xpos = x;
    ypos =y;
  } 
  void calc(){
    x1 = u * x0 * (1.0 - x0);
  }
  void plot(float y1,float y2){
    // if (y1 == Float.NaN) return;
    //if (y2 == Float.NaN) return;

    smooth();
    //fill(10);
    stroke(51);
    line((n*2)+xpos,h -(y1*h)+ypos,((n+1)*2)+xpos,h - (y2*h)+ ypos);
    n++;
  }
  void display(){ 
    noStroke();
    fill(255);
    rect(xpos,ypos,w,h);

    x0 = x = 0.1;
    while(n<w/2){
      calc();
      plot(x0,x1);
      n++;
      x0 = x1;
    }
    n = 0;
  } 
}

class Bifurcation{

  float w; // single bar width 
  float xpos; // rect xposition 
  float h; // rect height 
  float ypos ; // rect yposition 

  float start;
  float end;
  float x = 0.1;
  float u = 3.5;
  int n = 0;
  int xPlot = 0;
  float x0 = x; 
  float x1 = 0;
  boolean drawn = false;
  Bifurcation(float x, float y, float width, float height, float start, float end) { 
    w = width;
    h = height;
    xpos = x;
    ypos = y;
    this.start = start;
    this.end = end;
  } 

  void calc(){
    x1 = u * x0 * (1.0 - x0);
  }
  void display() 
  { 
    // if(!drawn){
    //   drawn = true;
    noStroke();
    fill(255);
    rect(xpos,ypos,w,h);
    while(xPlot <= w){
      u = ((xPlot/(w * 1.0)) * (end - start)) + start ;//+ 2.75;
      x0 = x = 0.1;
      while(n<100){
        calc();
        n++;
        x0 = x1;
      }
      while(n<300){
        calc();
        n++;
        plot(x0);
        x0 = x1;
      }
      n= 0;
      xPlot++;
    }
    // }
  } 
  void plot(float y2){
    smooth();
    stroke(51);
    point(xPlot + xpos,h - (y2*h)+ ypos);
  }
}

//Slider draggingSlider;
class Slider 
{ 

  float w; // single bar width 
  float xpos; // rect xposition 
  float h; // rect height 
  float ypos ; // rect yposition 
  float diam;
  float normv = 0; // single bar distance 

  float maxv;
  float minv;
  float xx;
  float yy;

  float offsetX;
  float offsetY;
  float indicator;




  boolean dragging = false;
  Slider(float x, float y, float width, float height, float diameter, float value, float min, float max, float indic) { 
    w = width;
    h= height;
    xpos = x;
    ypos =y;
    diam = diameter;
    normv = value;
    maxv = max;
    minv = min;
    indicator = indic;
    calcThumbCenter();
  } 
  void calcThumbCenter(){
    xx = xpos + (normv * w);
    yy = ypos + (h/2.0);
  }
  float value(){
    return ((maxv - minv) * normv)+minv;
  }
  void display() { 
    //text(value(),xpos + w,yy);
    noStroke();
    fill(255);
    rect(xpos,ypos,w,h);
    fill(0);
    text(value(),xpos  ,ypos + h);
    stroke(0);
    strokeWeight(1);
    // println(5);
    smooth();
    line(xpos ,ypos + (h/2), xpos + w, ypos + (h/2));
    ellipseMode(CENTER); 
    stroke(255,0,0);
    line(xx ,yy, xx, ypos + h + indicator);

    if (dragging)noFill();
    else fill(255);
    strokeWeight(1);
    smooth();
    smooth();
    ellipse(xx, yy, diam, diam);
    fill(0);
  } 
  boolean thumbCheck(float x, float y){
    return (diam/2.0) >= sqrt(sq(xx - x) + sq(yy-y));
  }
  void mousePressed(){
    if(thumbCheck(mouseX, mouseY)){
      dragging = true;
      offsetX =  mouseX - xx;
      // offsetY =  mouseY - yy;
    }
  } 
  void mouseDragged(){ 
    if(dragging){
      float newX = mouseX + offsetX;
      if(newX < xpos) newX = xpos;
      if (newX > xpos + w) newX = xpos + w;
      xx = newX;
      normv = (newX - xpos)/ w;
    }
    //calcThumbCenter;
  } 
  void mouseReleased(){ 
    dragging = false;
  }
} 
void mousePressed(){
  tSlider.mousePressed();
} 
void mouseDragged(){ 
  tSlider.mouseDragged();
} 
void mouseReleased(){ 
  tSlider.mouseReleased();
}